#!perl
use Cassandane::Tiny;

#
# Test that
#  - the $Foobar flag can be set
#  - the $Foobar flag can be cleared again
#  - cyr_expire -t can remove the $Foobar flag from the mailbox permanentflags
#
#
sub test_expunge_removeflag ($self)
{
    my $talk = $self->{store}->get_client();
    $self->{store}->_select();
    $self->assert_num_equals(1, $talk->uid());
    $self->{store}->set_fetch_attributes(qw(uid flags));

    my $perm = $talk->get_response_code('permanentflags');
    my @flags = grep { !m{^\\} } @$perm;
    $self->assert_deep_equals([], \@flags);

    xlog $self, "Add two messages";
    my %msg;
    $msg{A} = $self->make_message('Message A');
    $msg{A}->set_attributes(id => 1,
                            uid => 1,
                            flags => []);
    $msg{B} = $self->make_message('Message B');
    $msg{B}->set_attributes(id => 2,
                            uid => 2,
                            flags => []);
    $self->check_messages(\%msg);

    xlog $self, "Set \$Foobar on message A";
    my $res = $talk->store('1', '+flags', '($Foobar)');
    $self->assert_deep_equals({ '1' => { 'flags' => [ '$Foobar' ] }}, $res);
    $msg{A}->set_attribute(flags => ['$Foobar']);
    $self->check_messages(\%msg);

    xlog $self, "Clear \$Foobar on message A";
    $res = $talk->store('1', '-flags', '($Foobar)');
    $self->assert_deep_equals({ '1' => { 'flags' => [] }}, $res);
    $msg{A}->set_attribute(flags => []);
    $self->check_messages(\%msg);

    $self->{store}->disconnect();
    $self->{store}->connect();
    $self->{store}->_select();
    $talk = $self->{store}->get_client();

    $self->check_messages(\%msg);

    xlog $self, "Flag is still in the mailbox";

    $perm = $talk->get_response_code('permanentflags');
    @flags = grep { !m{^\\} } @$perm;
    $self->assert_deep_equals(['$Foobar'], \@flags);

    $self->{store}->disconnect();

    $self->{instance}->run_command({ cyrus => 1 }, 'cyr_expire', '-t');

    $self->{store}->connect();
    $self->{store}->_select();
    $talk = $self->{store}->get_client();

    $perm = $talk->get_response_code('permanentflags');
    @flags = grep { !m{^\\} } @$perm;
    $self->assert_deep_equals([], \@flags);
}
