#!perl
use Cassandane::Tiny;

#
# Test that
#  - the $Foobar flag can be set
#  - the $Foobar flag can be cleared again
#  - other messages don't get the $Foobar flag
#  - once set, it's persistent across sessions
#
# This is basically the same test as for \Flagged but with a user flag,
# which is an entirely different code path in the server.
#
sub test_userflag ($self)
{
    my $talk = $self->{store}->get_client();
    $self->{store}->_select();
    $self->assert_num_equals(1, $talk->uid());
    $self->{store}->set_fetch_attributes(qw(uid flags));

    xlog $self, "Add two messages";
    my %msg;
    $msg{A} = $self->make_message('Message A');
    $msg{A}->set_attributes(id => 1,
                            uid => 1,
                            flags => []);
    $msg{B} = $self->make_message('Message B');
    $msg{B}->set_attributes(id => 2,
                            uid => 2,
                            flags => []);
    $self->check_messages(\%msg);

    xlog $self, "Set \$Foobar on message A";
    my $res = $talk->store('1', '+flags', '($Foobar)');
    $self->assert_deep_equals({ '1' => { 'flags' => [ '$Foobar' ] }}, $res);
    $msg{A}->set_attribute(flags => ['$Foobar']);
    $self->check_messages(\%msg);

    xlog $self, "Clear \$Foobar on message A";
    $res = $talk->store('1', '-flags', '($Foobar)');
    $self->assert_deep_equals({ '1' => { 'flags' => [] }}, $res);
    $msg{A}->set_attribute(flags => []);
    $self->check_messages(\%msg);

    xlog $self, "Set \$Foobar on message A again";
    $res = $talk->store('1', '+flags', '($Foobar)');
    $self->assert_deep_equals({ '1' => { 'flags' => [ '$Foobar' ] }}, $res);
    $msg{A}->set_attribute(flags => ['$Foobar']);
    $self->check_messages(\%msg);

    xlog $self, "Reconnect, \$Foobar should still be on message A";
    $self->{store}->disconnect();
    $self->{store}->connect();
    $self->{store}->_select();
    $self->check_messages(\%msg);
}
