#!perl
use Cassandane::Tiny;

sub test_change_selected
    :needs_component_idled :min_version_3_9
    ($self)
{
    xlog $self, "Test of NOTIFY events following SELECTED mailbox";

    $self->{instance}->{config}->set(imapidlepoll => '2');
    $self->{instance}->add_start(name => 'idled',
                                 argv => [ 'idled' ]);
    $self->{instance}->start();

    my $svc = $self->{instance}->get_service('imap');

    my $store = $svc->create_store();
    my $talk = $store->get_client();

    my $otherstore = $svc->create_store();
    my $othertalk = $otherstore->get_client();

    xlog $self, "The server should report the NOTIFY capability";
    $self->assert($talk->capability()->{notify});

    xlog $self, "Create another mailbox";
    $talk->create("INBOX.foo");

    xlog $self, "Enable Notify";
    my $res = $talk->_imap_cmd('NOTIFY', 0, "", 'SET',
                               "(SELECTED (MessageNew MessageExpunge))",
                               "(PERSONAL (MessageNew MessageExpunge))");

    xlog $self, "Examine INBOX";
    $talk->examine("INBOX");
    $self->assert_num_equals(0, $talk->get_response_code('exists'));
    $self->assert_num_equals(0, $talk->get_response_code('recent'));
    $self->assert_num_equals(1, $talk->get_response_code('uidnext'));

    xlog $self, "Deliver a message";
    my $msg = $self->{gen}->generate(subject => "Message 1");
    $self->{instance}->deliver($msg);

    # Should get EXISTS, RECENT response
    $res = $store->idle_response({}, 3);
    $self->assert($res, "received an unsolicited response");
    $res = $store->idle_response({}, 3);
    $self->assert($res, "received an unsolicited response");
    $res = $store->idle_response({}, 1);
    $self->assert(!$res, "no more unsolicited responses");

    $self->assert_num_equals(1, $talk->get_response_code('exists'));
    $self->assert_num_equals(1, $talk->get_response_code('recent'));

    xlog $self, "Examine INBOX.foo";
    $talk->examine("INBOX.foo");
    $self->assert_num_equals(0, $talk->get_response_code('exists'));
    $self->assert_num_equals(0, $talk->get_response_code('recent'));
    $self->assert_num_equals(1, $talk->get_response_code('uidnext'));

    xlog $self, "MOVE message from INBOX to INBOX.foo in other session";
    $othertalk->select("INBOX");
    $res = $othertalk->move('1', "INBOX.foo");

    # Should get EXISTS, RECENT response for INBOX.foo and STATUS response for INBOX
    $res = $store->idle_response({}, 3);
    $self->assert($res, "received an unsolicited response");
    $res = $store->idle_response({}, 3);
    $self->assert($res, "received an unsolicited response");
    $res = $store->idle_response('STATUS', 3);
    $self->assert($res, "received an unsolicited response");
    $res = $store->idle_response({}, 1);
    $self->assert(!$res, "no more unsolicited responses");

    $self->assert_num_equals(1, $talk->get_response_code('exists'));
    $self->assert_num_equals(1, $talk->get_response_code('recent'));

    my $status = $talk->get_response_code('status');
    $self->assert_num_equals(0, $status->{'INBOX'}{messages});
    $self->assert_num_equals(2, $status->{'INBOX'}{uidnext});
}
