#!perl
use Cassandane::Tiny;

sub test_downgrade_upgrade ($self)
{
    my $talk = $self->{store}->get_client();
    $self->{store}->_select();
    $self->assert_num_equals(1, $talk->uid());
    $self->{store}->set_fetch_attributes(qw(uid flags));

    xlog $self, "Add two messages";
    my %msg;
    $msg{A} = $self->make_message('Message A');
    $msg{A}->set_attributes(id => 1,
                            uid => 1,
                            flags => []);
    $msg{B} = $self->make_message('Message B');
    $msg{B}->set_attributes(id => 2,
                            uid => 2,
                            flags => []);
    $self->check_messages(\%msg);

    xlog $self, "Set \\Seen on message A";
    my $res = $talk->store('1', '+flags', '(\\Seen)');
    $self->assert_deep_equals({ '1' => { 'flags' => [ '\\Seen' ] }}, $res);
    $msg{A}->set_attribute(flags => ['\\Seen']);
    $self->check_messages(\%msg);

    xlog $self, "Clear \\Seen on message A";
        $res = $talk->store('1', '-flags', '(\\Seen)');
    $self->assert_deep_equals({ '1' => { 'flags' => [] }}, $res);
    $msg{A}->set_attribute(flags => []);
    $self->check_messages(\%msg);

    xlog $self, "Set \\Seen on message A again";
    $res = $talk->store('1', '+flags', '(\\Seen)');
    $self->assert_deep_equals({ '1' => { 'flags' => [ '\\Seen' ] }}, $res);
    $msg{A}->set_attribute(flags => ['\\Seen']);
    $self->check_messages(\%msg);

    for my $version (19, 18, 17, 16, 15, 14, 13, 12, 10, 9, 8, 7, 6) {
        xlog $self, "Set to version $version";
        $self->{instance}->run_command({ cyrus => 1 }, 'reconstruct', '-V', $version);

        xlog $self, "Reconnect, \\Seen should still be on message A";
        $self->{store}->disconnect();
        $self->{store}->connect();
        $self->{store}->_select();
        $self->check_messages(\%msg);
    }

    for my $version (6, 7, 8, 9, 10, 12, 13, 14, 15, 16, 17, 18, 19, 'max') {
        xlog $self, "Set to version $version";
        $self->{instance}->run_command({ cyrus => 1 }, 'reconstruct', '-V', $version);

        xlog $self, "Reconnect, \\Seen should still be on message A";
        $self->{store}->disconnect();
        $self->{store}->connect();
        $self->{store}->_select();
        $self->check_messages(\%msg);
    }
}
