#!perl
use Cassandane::Tiny;

sub test_imip_invite_calendarid
    :needs_component_httpd :want_service_http
    ($self)
{
    my $IMAP = $self->{store}->get_client();
    $self->{store}->_select();
    $self->assert_num_equals(1, $IMAP->uid());
    $self->{store}->set_fetch_attributes(qw(uid flags));

    xlog $self, "Create calendar user and second calendar";
    my $CalDAV = $self->{caldav};
    my $CalendarId = $CalDAV->NewCalendar({name => 'foo'});
    $self->assert_not_null($CalendarId);

    my $uuid = "6de280c9-edff-4019-8ebd-cfebc73f8201";

    xlog $self, "Install a sieve script to process iMIP using legacy calendar id";
    $self->{instance}->install_sieve_script(<<EOF
require ["body", "variables", "imap4flags", "processcalendar"];
if body :content "text/calendar" :contains "\nMETHOD:" {
    processcalendar :calendarid "$CalendarId" :outcome "outcome";
    if string "\${outcome}" "added" {
        setflag "\\\\Flagged";
    }
}
EOF
    );

    my $imip = <<EOF;
Date: Thu, 23 Sep 2021 09:06:18 -0400
From: Foo <foo\@example.net>
To: Cassandane <cassandane\@example.com>
Message-ID: <$uuid\@example.net>
Content-Type: text/calendar; method=REQUEST; component=VEVENT
X-Cassandane-Unique: $uuid

BEGIN:VCALENDAR
VERSION:2.0
PRODID:-//Apple Inc.//Mac OS X 10.10.4//EN
METHOD:REQUEST
BEGIN:VEVENT
CREATED:20210923T034327Z
UID:$uuid
DTEND;TZID=America/New_York:20210923T183000
TRANSP:OPAQUE
SUMMARY:An Event
DTSTART;TZID=America/New_York:20210923T153000
DTSTAMP:20210923T034327Z
SEQUENCE:0
ORGANIZER;CN=Test User:MAILTO:foo\@example.net
ATTENDEE;CN=Test User;PARTSTAT=ACCEPTED;RSVP=TRUE:MAILTO:foo\@example.net
ATTENDEE;PARTSTAT=NEEDS-ACTION;RSVP=TRUE:MAILTO:cassandane\@example.com
END:VEVENT
END:VCALENDAR
EOF

    xlog $self, "Deliver iMIP invite";
    my $msg = Cassandane::Message->new(raw => $imip);
    $msg->set_attribute(uid => 1,
                        flags => [ '\\Recent', '\\Flagged' ]);
    $self->{instance}->deliver($msg);

    xlog $self, "Check that the message made it to INBOX";
    $self->check_messages({ 1 => $msg }, check_guid => 0);

    xlog $self, "Check that the event made it to calendar";
    my $events = $CalDAV->GetEvents($CalendarId);
    $self->assert_equals(1, scalar @$events);
    $self->assert_str_equals($uuid, $events->[0]{uid});

    my $jmap = $self->{jmap};
    my $res = $jmap->CallMethods([['Calendar/get', {}, "R1"]]);

    my %calendars = map { $_->{name} => $_ } @{$res->[0][1]{list}};
    my $jmapid = $calendars{'foo'}{id};
    $self->assert_not_null($jmapid);

    xlog $self, "Install a sieve script to process iMIP using JMAP calendar id";
    $self->{instance}->install_sieve_script(<<EOF
require ["body", "variables", "imap4flags", "processcalendar"];
if body :content "text/calendar" :contains "\nMETHOD:" {
    processcalendar :calendarid "$jmapid" :outcome "outcome";
    if string "\${outcome}" "added" {
        setflag "\\\\Flagged";
    }
}
EOF
    );

    # Change Message-ID
    $imip =~ s/f8201\@/f8201-1\@/;

    # Update Event
    $imip =~ s/An Event/An Updated Event/;
    $imip =~ s/T1830/T1930/;
    $imip =~ s/SEQUENCE:0/SEQUENCE:1/;

    xlog $self, "Deliver iMIP invite";
    my $msg2 = Cassandane::Message->new(raw => $imip);
    $msg2->set_attribute(uid => 2, flags => [ '\\Recent' ]);
    $self->{instance}->deliver($msg2);

    xlog $self, "Check that the message made it to INBOX";
    $self->check_messages({ 1 => $msg, 2 => $msg2 },
                          keyed_on => 'uid', check_guid => 0);

    xlog $self, "Check that the event made it to calendar";
    $events = $CalDAV->GetEvents($CalendarId);

    $self->assert_equals(1, scalar @$events);
    $self->assert_str_equals($uuid, $events->[0]{uid});
    $self->assert_str_equals('PT4H', $events->[0]{duration});
    $self->assert_str_equals('An Updated Event', $events->[0]{title});
    $self->assert_num_equals(1, $events->[0]{sequence});
}
